本帖最后由 dengyu 于 2018-1-18 22:16 编辑
ModTweaker Wiki翻译
1.11.2版
实用拓展

对象支持
以下对象已经受支持：
  • 原子再构机
  • 毛球
  • 咖啡制造机
  • 堆肥机
  • 磨粉机
  • 充能台
  • 藏宝箱

下面这些合成可以添加或者删除：
被红色标记的参数是可选参数，它可以被排除。
//原子再构机
//添加合成
//OutputStack, InputStack, Energy
//参数：输出物品，需要物品，所需能量
mods.actuallyadditions.AtomicReconstructor.addRecipe(<minecraft:fire_charge>, <minecraft:coal:1>, 1000);
//移除合成
//OutputStack
//参数：输出物品
mods.actuallyadditions.AtomicReconstructor.removeRecipe(<minecraft:coal>);

//毛球
//添加掉落物
//OutputStack, Chance
//参数：掉落物品，几率
mods.actuallyadditions.BallOfFur.addReturn(<minecraft:string>, <minecraft:coal:1>, 5);
//移除掉落物
//OutputStack
//参数：掉落物品
mods.actuallyadditions.BallOfFur.removeReturn(<minecraft:coal>);

//咖啡制造机
//添加合成
//InputStack, EffectArray, DurationArray, Amplifier
//参数：需要物品，效果（可多选，用逗号隔开），持续时间（可多选，用逗号隔开），放大倍数
mods.actuallyadditions.Coffee.addRecipe(<minecraft:netherrack>, ["swiftness"], [1], 10);
//移除合成
//InputStack
//参数：需要物品
mods.actuallyadditions.Coffee.removeRecipe(<minecraft:sugar>);

//堆肥机
//添加合成
//OutputStack, OutputDisplay, InputStack, InputDisplay
//参数：发酵完物品，发酵时机器外观物品，需要物品，发酵时机器外观物品
mods.actuallyadditions.Compost.addRecipe(<minecraft:dirt>, <minecraft:dirt>, <minecraft:sugar>, <minecraft:snow>);
//移除合成
//InputStack
//参数：需要物品
mods.actuallyadditions.Compost.removeRecipe(<actuallyadditions:itemCanolaSeed>);

//磨粉机
//添加合成
//OutputStack, InputStack, Output2Stack, Output2Chance
//参数：主产品, 需要物品, 副产品, 副产品出现几率
mods.actuallyadditions.Crusher.addRecipe(<minecraft:iron_ingot>, <minecraft:iron_ore>, <minecraft:stone>, 50);
//移除合成
//InputStack
//参数：需要物品
mods.actuallyadditions.Crusher.removeRecipe(<minecraft:gold_ore>);

//充能台
//添加合成
//OutputStack, InputStack, Modifier1, Modifier2, Modifier3, Modifier4, EnergyPerStand, TimeInTicks, ParticleColourArray
//参数：输出物品, 需要物品, 充能要件1, 充能要件2, 充能要件3, 充能要件4, 每站一会儿获得能量, 需要时间（单位：Ticks）, 充能粒子颜色（在数组中用RGB三数据填入）
mods.actuallyadditions.Empowerer.addRecipe(<minecraft:gold_ingot>, <minecraft:iron_ingot>, <minecraft:redstone>, <minecraft:redstone>, <minecraft:redstone>, <minecraft:redstone>, 500, 100, [0.5, 0.3, 0.2]);
//移除合成
//OutputStack
//参数：输出物品
mods.actuallyadditions.Empowerer.removeRecipe(<actuallyadditions:itemCrystalEmpowered:4>);

//藏宝箱
//添加宝物
//LootStack, Chance, MinAmount, MaxAmount
//参数：宝物，几率，最小获得数，最大获得数
mods.actuallyadditions.TreasureChest.addLoot(<minecraft:dirt>, 50, 1, 64);
//移除宝物
//LootStack
//参数：宝物
mods.actuallyadditions.TreasureChest.removeLoot(<minecraft:gold>);









ModTweaker Wiki翻译
1.11.2版
凿子

对象支持
以下对象已经受支持：
  • 变化集合
  • 变化

变化集合包含了所有可以被凿子所改变的事件，这一事件称之为“变化”。比如说变化“Cyan Hex Plating”应该在“Variation of the Group Hex Plating”这一变化集合中。

下面这些合成可以添加或者删除：


被红色标记的参数是可选参数，它可以被排除。
//变化集合
//添加集合
//Group
//参数：变化集合名称
mods.chisel.Groups.addGroup("hardenedclay");
//移除集合
//Group
//参数：变化集合名称
mods.chisel.Groups.removeGroup("andesite");

//变化
//添加变化
//Group, ItemStack
//参数：变化集合名称，变化成为的物品
mods.chisel.Groups.addVariation("hardenedclay", <minecraft:stained_hardened_clay:*>);
//移除变化
//ItemStack
//参数：变化成为的物品
mods.chisel.Groups.removeVariation(<chisel:hexPlating>);




ModTweaker Wiki翻译
1.11.2版
林业

对象支持
以下对象已经受支持：
  • 木工机
  • 离心机
  • 发酵机
  • 加湿机
  • 榨汁机
  • 蒸馏机
  • 热电子合成器

下面这些合成可以添加或者删除：


被红色标记的参数是可选参数，它可以被排除。
//木工机
//添加合成
//OutputStack, InputArray, Time in Ticks, InputFluid, BoxStack
//参数：输出物品，需要物品，时间（单位：Ticks），需要流体，容器
mods.forestry.Carpenter.addRecipe(<forestry:oakStick> * 2,
  [[null, <ore:stickWood>, null],
  [<minecraft:planks>, null, <minecraft:planks>],
  [null, <minecraft:planks>, null]], 20, <liquid:seed.oil> * 100, <minecraft:log>);
//移除合成
//OutputStack, InputFluid
//参数：输出物品，需要流体
mods.forestry.Carpenter.removeRecipe(<forestry:impregnatedCasing>, <liquid:seed.oil>);

//离心机
//添加合成
//OutputArray, % Percentage, InputStack, Time in Ticks
//输出物品 % 百分数，需要物品，时间（单位：Ticks）
mods.forestry.Centrifuge.addRecipe([<minecraft:leaves> % 200, <minecraft:stick> % 80, <forestry:beeCombs> % 20], <minecraft:sapling>, 20);
//移除合成
//InputStack
//参数：需要物品
mods.forestry.Centrifuge.removeRecipe(<forestry:beeCombs>);

//发酵机
//添加合成
//OutputFluid, InputStack, FluidInput, FermentationValue, FluidOutputModifier
//参数：输出流体，需要物品，需要流体，流体发酵值（决定了合成时需要流体的数量），流体输出调节
mods.forestry.Fermenter.addRecipe(<liquid:for.honey>, <minecraft:sugar>, <liquid:water>, 100, 2);

//移除合成
//InputStack
//参数：需要物品
mods.forestry.Fermenter.removeRecipe(<minecraft:reeds>);
//添加燃料
//InputStack, CycleAmount, BurnDuration
//参数：燃料名字，循环周期，燃烧耐久
mods.forestry.Fermenter.addFuel(<minecraft:dirt:2>, 1000, 1000);
//移除燃料
//InputStack
//参数：燃料名字
mods.forestry.Fermenter.removeFuel(<minecraft:stone:1>);

//加湿机
//添加合成
//OutputStack, InputStack, Time in Ticks
//参数：输出物品，需要物品，时间（单位：Ticks）
mods.forestry.Moistener.addRecipe(<minecraft:grass>, <minecraft:dirt>, 5000);

//移除合成
//OutputStack
//参数：输出物品
mods.forestry.Moistener.removeRecipe(<minecraft:mycelium>);
//添加燃料
//InputStack, OutputStack, MoistenerValue, Priority
//参数：需要物品，输出物品，湿润值，优先级
mods.forestry.Moistener.addFuel(<minecraft:seeds>, <minecraft:dye:15>, 20, 1);
//移除燃料
//InputStack

//参数：需要物品
mods.forestry.Moistener.removeFuel(<minecraft:wheat>);

//榨汁机
//添加合成
//OutputFluid, InputArray, Time in Ticks, OutputStack + %
//参数：输出流体，需要物品，时间（单位：Ticks），副产物+ % 数字
mods.forestry.Squeezer.addRecipe(<liquid:ice> * 1000, [<minecraft:packed_ice> * 4, <minecraft:snowball>], 20, <forestry:craftingMaterial:5> % 50);
//移除合成
//OutputFluid, InputArray
//参数：输出流体，需要物品
mods.forestry.Squeezer.removeRecipe(<liquid:water>, [<minecraft:cactus>]);

//蒸馏机
//添加合成
//OutputFluid, InputFluid, Time in Ticks
//参数：输出流体，输入流体，时间（Ticks）
mods.forestry.Still.addRecipe(<liquid:bio.ethanol> * 20, <liquid:juice> * 20, 100);
//移除合成
//OutputFluid, InputFluid
//参数：输出流体，输入流体
mods.forestry.Still.removeRecipe(<liquid:bio.ethanol>, <liquid:biomass>);

//热电子合成器
//添加冶炼表
//MoltenGlassOutput, InputStack, MeltingTemperature
//参数：输出的熔融玻璃，输入物品，融化所需温度
mods.forestry.ThermionicFabricator.addSmelting(375, <minecraft:stained_glass_pane>, 1000);
//移除冶炼表
//InputStack
//参数：输入物品
mods.forestry.ThermionicFabricator.removeSmelting(<minecraft:sand>);
//添加铸造合成表
//OutputStack, InputArray, MoltenGlassInput, CastInput
//参数：输出物品，需要物品，需要的熔融玻璃，熔融材料
mods.forestry.ThermionicFabricator.addCast(<minecraft:beacon>, [
  [<ore:paneGlass>, <ore:paneGlass>, <ore:paneGlass>],
  [<ore:paneGlass>, <minecraft:nether_star>, <ore:paneGlass>],
  [<minecraft:obsidian>, <minecraft:obsidian>, <minecraft:obsidian>]], 1000, <forestry:waxCast:*>);
//移除铸造合成表
//OutputStack
//参数：输出物品
mods.forestry.ThermionicFabricator.removeCast(<minecraft:stained_glass>);




ModTweaker Wiki翻译
1.11.2版
精致存储


对象支持
以下对象已经受支持：
  • 压印器
下面这些合成可以添加或者删除：
被红色标记的参数是可选参数，它可以被排除。
//压印器
//添加合成
//OutputStack, Time in Ticks, InputArray
//参数：目标物品, 需要时间（单位：Tick）, 需要物品
mods.refinedstorage.Solderer.addRecipe(<minecraft:diamond>, 5
  [[<minecraft:coal>, null, <minecraft:coal>],
  [<minecraft:coal>, <minecraft:coal>, <minecraft:coal>],
  [<minecraft:obsidian>, <minecraft:obsidian>, <minecraft:obsidian>]]);
//移除合成
//OutputStack
//参数：目标物品
mods.refinedstorage.Solderer.removeRecipe(<minecraft:iron_ingot>);